/**
 * 
 *  Copyright (c) 2008 Marc Hughes 
 * 
 *  Permission is hereby granted, free of charge, to any person obtaining a 
 *  copy of this software and associated documentation files (the "Software"), 
 *  to deal in the Software without restriction, including without limitation 
 *  the rights to use, copy, modify, merge, publish, distribute, sublicense, 
 *  and/or sell copies of the Software, and to permit persons to whom the Software 
 *  is furnished to do so, subject to the following conditions:
 * 
 *  The above copyright notice and this permission notice shall be included in all 
 *  copies or substantial portions of the Software.
 * 
 *  THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR IMPLIED, 
 *  INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY, FITNESS FOR A 
 *  PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT 
 *  HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION 
 *  OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE 
 *  SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE. 
 * 
 **/
package com.roguedevelopment.util
{
	import flash.filesystem.File;
	
	/**
	 * This is a class that keeps track of your temporary files & directories and then has a cleanup() call
	 * that will delete them all.  That's useful to call at program shutdown.
	 **/
	public class TempFileUtil
	{
		protected static var tmpFiles:Array = [];
		
		
		public static function getTempDirectory() : File
		{
			var rv:File = File.createTempDirectory();
			addTempFile( rv );
			return rv;
		}
		
		
		public static function getTempFile() : File
		{
			var rv:File = File.createTempFile();
			addTempFile( rv );
			return rv;
		}
		
		public static function addTempFile( file:File ) : void
		{
			tmpFiles.push(file);	
		}
		
		public static function cleanup() : void
		{
			for each ( var f:File in tmpFiles )
			{
				try
				{
					if( f.exists )
					{
						if( f.isDirectory )
						{
							f.deleteDirectory( true );
						}
						else
						{
							f.deleteFile();
						}
					}
				}
				catch( error:Error )
				{
					trace("TempFileUtil::cleanup() Warning: " + error.message );
					// We'll ignore all errors since this is usually called at shutdown and is just a cleanup. 					
				}
			}			
			tmpFiles = [];
		}
	}
}